鯖主のためのMinecraftPEサーバーwiki

ここでは、自動再起動の仕方についてお話します
ASRやAutoStopなどの自動サーバー再起動プラグインと呼ばれているプラグインがありますが
実は、プラグインの導入だけで"自動再起動"させることはできないのです。
自動再起動させるにはstart.cmd or start.sh　を書き換える必要があります！！

Loop.cmd Loop.sh とは start.cmd start.shを自動再起動仕様に中身のコードを改変したものです
以下に改変されたコードがあります
startファイルとは別に、新しくファイルを作り
ファイル内に以下のコードをコピー&ペ-ストでもいいので書き、loopファイルを作成しましょう

@echo off
TITLE PocketMine-MP server software for Minecraft: Pocket Edition
cd /d %~dp0

netstat -o -n -a | findstr 0.0.0.0:19132>nul
if %ERRORLEVEL% equ 0 (
    echo Your server is running.
    goto :loop
) ELSE (
    echo Starting your PocketMine-MP server.
    goto :ReStart
)


:loop
echo Checking if server is online...
PING 127.0.0.1 -n 10 >NUL


netstat -o -n -a | findstr 0.0:19132>nul
if %ERRORLEVEL% equ 0 (
    echo Server is running.
    goto :loop
) ELSE (
    echo Starting PocketMine-MP in 10 seconds...
    PING 127.0.0.1 -n 10 >NUL
    goto :ReStart
)


:ReStart
if exist bin\php\php.exe (
    set PHP_BINARY=bin\php\php.exe
) else (
    set PHP_BINARY=php
)


if exist PocketMine-MP.phar (
	set POCKETMINE_FILE=PocketMine-MP.phar
) else (
	if exist src\pocketmine\PocketMine.php (
		set POCKETMINE_FILE=src\pocketmine\PocketMine.php
	) else (
		echo "Couldn't find a valid PocketMine-MP installation"
		pause
		exit 1
	)
)

if exist bin\mintty.exe (
	start "" bin\mintty.exe -o Columns=88 -o Rows=32 -o AllowBlinking=0 -o FontQuality=3 -o Font="DejaVu Sans Mono" -o FontHeight=10 -o CursorType=0 -o CursorBlinks=1 -h error -t "PocketMine-MP" -i bin/pocketmine.ico -w max %PHP_BINARY% %POCKETMINE_FILE% --enable-ansi %*
) else (
	%PHP_BINARY% -c bin\php %POCKETMINE_FILE% %*
)
goto :loop

@echo off

rem Jupiter 起動バッチファイル(Windows専用)

rem 作成: Itsu
rem 最終更新: 2017/8/30 13:51


setlocal enabledelayedexpansion

rem Autorestart変数が0の場合は自動再起動、それ以外は終了
set Autorestart=0

rem count変数は起動回数の保持に使われます。いじらないでください。
set count=1

rem Soft変数は起動するjarの名前です。
set Soft=nukkit-1.0-SNAPSHOT.jar



goto Main

:Main
	if not exist %Soft% (
		goto Finish
	)
	
	cls
	chcp 932 > nul
	
	echo !count!回目の起動です。
	
	java -Djline.terminal=jline.UnsupportedTerminal -jar %Soft%
	
	goto END

:Finish
	echo %Soft%がありません。
	echo キーを押して終了してください。
	pause > nul

:END
	if %Autorestart%==0 (
		set /a count=!count!+1
		goto Main
	)

	timeout /t 1 > nul